Vfrdtyky

How would I go about counting the number of words in a specific attribute for each element?

Example: I want to count how many cities each country has, and cities are attributes like this: world/country/[@cities]. I then want to display this as a new list which displays each country and the number of cities that each country has.

I have tried this:

for $country in doc("world.xml")/world/country

let $neighbors := tokenize($country/@cities, 's+')

let $count := count($neighbors)

order by $count

return ($country/name, $count)

But how do I get max of the count?

There are a few approaches one might take. Following your start to its logical conclusion, you've already ordered your items by $count, so you can bind these ordered items to a variable and retrieve the greatest one using the fn:last() function. You didn't provide source data, so here's a complete example demonstrating the approach:

xquery version "3.1";



let $people := 

    <people>

        <person age="42" name="molly"/>

        <person age="70" name="lucy"/>

        <person age="9" name="billy"/>

    </people>

let $ordered := 

    (

        for $person in $people/person

        order by $person/@age cast as xs:integer

        return

            $person

    )

let $oldest := $ordered[last()]

return

    $oldest

This will return the Lucy entry. (If we hadn't cast the values as xs:integer we would've gotten Billy.)

However, it's possible there will be two or more people who have the same greatest age. To return all entries with the maximum age, you could first find the maximum value, then select the items with that value:

xquery version "3.1";



let $people := 

    <people>

        <person age="42" name="molly"/>

        <person age="70" name="lucy"/>

        <person age="9" name="billy"/>

        <person age="70" name="holly"/>

    </people>

let $ages := $people/person/@age

let $max := max($ages)

let $oldest := $people/person[@age = $max]

return

    $oldest

This will return the Lucy and Holly entries. (We didn't have to cast the values as integer in this case because the fn:max() function casts all values of type xs:anyAtomicType as xs:double; see https://www.w3.org/TR/xpath-functions-31/#func-max.)

Or, in a more compact form:

xquery version "3.1";



let $people := 

    <people>

        <person age="42" name="molly"/>

        <person age="70" name="lucy"/>

        <person age="9" name="billy"/>

        <person age="70" name="holly"/>

    </people>

return

    $people/person[@age = max($people/person/@age)]

Guessing from your code, I think max with for should work using XPath 2.0+

max(for $country in doc("world.xml")/world/country

    return count(tokenize($country/@cities, 's+')))

and then select the corresponding nodes

/world/country[count(tokenize(@cities, 's+')) = max(for $country in /world/country

    return count(tokenize($country/@cities, 's+')))]