Vfrdtyky

I have a bot deployed on Azure using MS Bot framework and the App Insights has been enabled. All users using the bot are AD authenticated users. We can see summary information on the Bot Analytics section like count of distinct users, activities, retention etc. However we like to know the behavior of a specific user (user id). How do I find a user specific information? I tried using the Analytic Queries but was not able to find which underlying tables would hold that sort of information.

I have a feeling I will have to code in telemetry to capture that information but the fact that Azure knows there are distinct users tells me the user id's would be stores somewhere. Any ideas?

My understanding is that Application Insights is generalized to work with multiple types of applications. You may notice that the tables all have user_id columns, but that user_id isn't used for bot purposes. Bot-specific information can be found in the customEvents table, since that table is used to store information that's specific to whatever type of application we have. The customEvents table has an object-typed column called customDimensions and the user "ID" is retrieved from that column through each object's "from" or "From ID" field.

Bot Analytics

The Bot Analytics blade is populated using the following queries:

let usersByDay = customEvents

    | where name == 'Activity' and timestamp >= startofday(ago(10d)) and timestamp <= startofday(now())

    | extend from = customDimensions['from']

    | extend from = tostring(iff(isnull(from), customDimensions['From ID'], from))

    | extend channel = customDimensions['channel']

    | extend channel = tostring(iff(isnull(channel), customDimensions['Channel ID'], channel))

    | summarize results = dcount(from) by bin(timestamp, 1d), from, channel;

usersByDay

    | join kind = leftouter usersByDay on from and channel

    | where timestamp <= timestamp1 and timestamp<startofday(ago(1d))

    | project timestamp, from = from, channel = channel, activity_time = timestamp1

    | summarize event_count = dcount(from) by timestamp, activity_time, channel

    | order by timestamp asc

Timeline:

customEvents

    | where name == 'Activity'

    | extend from = customDimensions['from']

    | extend from = tostring(iff(isnull(from), customDimensions['From ID'], from))

    | extend channel = customDimensions['channel']

    | extend channel = tostring(iff(isnull(channel), customDimensions['Channel ID'], channel))

    | extend activityType = customDimensions['Activity type']

    | where activityType != 'conversationUpdate'

    | summarize event_count = dcount(from) by bin(timestamp, 1d), channel

    | order by timestamp asc

    | project timestamp = timestamp, customDimensions_channel = channel, event_count

Totals:

customEvents

    | where name == 'Activity'

    | extend from = customDimensions['from']

    | extend from = tostring(iff(isnull(from), customDimensions['From ID'], from))

    | extend channel = customDimensions['channel']

    | extend channel = tostring(iff(isnull(channel), customDimensions['Channel ID'], channel))

    | extend activityType = customDimensions['Activity type']

    | where activityType != 'conversationUpdate'

    | summarize event_count = dcount(from) by channel

    | project customDimensions_channel = channel, event_count

Timeline:

customEvents

    | where name == 'Activity'

    | extend channel = customDimensions['channel']

    | extend channel = tostring(iff(isnull(channel), customDimensions['Channel ID'], channel))

    | summarize event_count = count() by bin(timestamp, 1d), channel

    | order by timestamp asc

    | project timestamp = timestamp, customDimensions_channel = channel, event_count

Totals:

customEvents

    | where name == 'Activity'

    | extend channel = customDimensions['channel']

    | extend channel = tostring(iff(isnull(channel), customDimensions['Channel ID'], channel))

    | summarize event_count = count() by channel

    | project customDimensions_channel = channel, event_count

Custom queries

The queries can be adapted to filter events for a specific user ID like this:

customEvents

    | extend from = customDimensions['from']

    | extend from = tostring(iff(isnull(from), customDimensions['From ID'], from))

    | extend activityType = customDimensions['Activity type']

    | where from == "some_user_id"

Make sure you've derived the user ID from one of the ID's that are actually in the data. You can see the available ID's by examining the from column in a query that includes it, like this:

customEvents

    | extend from = customDimensions['from']

    | extend from = tostring(iff(isnull(from), customDimensions['From ID'], from))